通達信量柱王子指標公式
2020/12/26 18:38:00
綠低量:=10;
藍低量:=50;
灰低量:=100;
H_L:=0.1*CONST(HHV(VOL,240));
{MAV10:MA(V,10),COLORYELLOW;}
異動135:MA(V,135),COLORMAGENTA;
洗盤40:MA(V,40),COLORBLUE;
啟動5:MA(V,5),COLORWHITE;
VVOL:=IF(CURRBARSCOUNT=1 AND PERIOD=5,VOL*240/FROMOPEN,DRAWNULL);{模擬量}
STICKLINE(CURRBARSCOUNT=1 AND PERIOD=5,VVOL,0,1,-1),COLOR00C0C0;
量:VOL,VOLSTICK,COLORLIGRAY;
換手: VOL*10000/FINANCE(7),NODRAW,COLORGREEN; {DYNAINFO(37)*100}
全換手周期: SUMBARS(V,CAPITAL),NODRAW,COLORLIGREEN;{求完全換手到現在的周期數}
量比: V/REF(MA(V,5),1),COLORBROWN,NODRAW;
幾倍: V/REF(V,1),COLORYELLOW,NODRAW;
倍數:=1.9;
倍量: VOL>=REF(V,1)*倍數 AND (IF(C<O,C>REF(C,1),1)),COLORYELLOW,NODRAW;
倍縮: REF(V,1)>=VOL*倍數,COLORMAGENTA,NODRAW;
平量: RANGE(V/REF(V,1),0.97,1.03) AND BARSCOUNT(V)>=2,COLORWHITE,NODRAW;
低量10: VOL=LLV(VOL,綠低量) AND BARSCOUNT(V)>=綠低量,COLORGREEN,NODRAW;
低量50: VOL=LLV(VOL,藍低量) AND BARSCOUNT(V)>=藍低量,COLORBLUE,NODRAW;
地量: VOL=LLV(VOL,灰低量) AND BARSCOUNT(V)>=灰低量,COLORGRAY,NODRAW;
V1:=VOL*0.95;{圖標位置}
V2:=VOL*0.85;
STICKLINE(倍量, 0,V1,1,0),COLORYELLOW;
STICKLINE(平量,0,V1,1,0),COLORWHITE;
STICKLINE(低量10,0,V2,1,0),COLORLIGREEN;
STICKLINE(低量50,0,V2,1,0),COLORBLUE;
STICKLINE(地量,0,V2,1,0),COLORGRAY;
STICKLINE(倍縮,0,V*0.45,1,0),COLORMAGENTA;
STICKLINE(C<O AND C>REF(C,1),0,V1,0,0),COLORRED;{假陰柱}
真陽或假陰:=C>O OR C>REF(C,1);
收陽:= REF(真陽或假陰,3);
倍量1:=REF(倍量,3);
高量:=REF(V,3)>=HHV(V,7);
三日不破:= LLV(C,3)>=REF(L,3);
價升:=COUNT(C>=REF(C,1),3)=3;{收盤價逐升}
量縮:=COUNT(V<=REF(V,1),3)=3;
連陽:= COUNT(真陽或假陰,3)=3;
倍量將軍柱:= 倍量1 AND 三日不破 AND 收陽;
高量將軍柱:= 高量 AND 三日不破 AND 收陽;
將軍柱:= 倍量將軍柱 OR 高量將軍柱;
黃金柱:= 將軍柱 AND 價升 AND 量縮 AND 連陽 ;{標準黃金柱}
STICKLINE(黃金柱,0.3*V,0.7*V,1,0),COLORRED; {紅柱}
DRAWICON(黃金柱,V*1.5,1);
DRAWTEXT(黃金柱 ,V+1.6*H_L,'黃金柱');
V100:= V<=LLV(V,100)*1.2 AND V>0 AND BARSCOUNT(V)>=100;
百日地量群:=COUNT(V100,5)>=3;
DRAWTEXT(FILTER(百日地量群,4),V+3*H_L,'地量群'),COLORGRAY;
長陰短柱:=C/REF(C,1)<=0.96 AND V<HHV(V,30)/1.9;
DRAWTEXT(長陰短柱 ,V+1.6*H_L,'長陰短柱'),COLORLICYAN;
看 股吧公式 www.ka nguba.com
其它股票公式列表
